1 %top {
2 /* Must come first for _LARGE_FILE_API on AIX. */
3 #include <config.h>
4
5 /*
6 * Must come first to avoid warnings on Windows.
7 *
8 * Flex-generated scanners may only include <inttypes.h> if __STDC_VERSION__
9 * is defined with a value >= 199901, meaning "full C99", and MSVC may not
10 * define it with that value, because it isn't 100% C99-compliant, even
11 * though it has an <inttypes.h> capable of defining everything the Flex
12 * scanner needs.
13 *
14 * We, however, will include it if we know we have an MSVC version that has
15 * it; this means that we may define the INTn_MAX and UINTn_MAX values in
16 * scanner.c, and then include <stdint.h>, which may define them differently
17 * (same value, but different string of characters), causing compiler warnings.
18 *
19 * If we include it here, and they're defined, that'll prevent scanner.c
20 * from defining them. So we include <pcap/pcap-inttypes.h>, to get
21 * <inttypes.h> if we have it.
22 */
23 #include <pcap/pcap-inttypes.h>
24
25 /*
26 * grammar.h requires gencode.h and sometimes breaks in a polluted namespace
27 * (see ftmacros.h), so include it early.
28 */
29 #include "gencode.h"
30 #include "grammar.h"
31
32 #include "diag-control.h"
33
34 /*
35 * Convert string to 32-bit unsigned integer; the string starts at
36 * string and is string_len bytes long.
37 *
38 * On success, sets *val to the value and returns 1.
39 * On failure, sets the BPF error string and returns 0.
40 *
41 * Also used in gencode.c
42 */
43 typedef enum {
44 STOULEN_OK,
45 STOULEN_NOT_HEX_NUMBER,
46 STOULEN_NOT_OCTAL_NUMBER,
47 STOULEN_NOT_DECIMAL_NUMBER,
48 STOULEN_ERROR
49 } stoulen_ret;
50
51 stoulen_ret stoulen(const char *string, size_t stringlen, bpf_u_int32 *val,
52 compiler_state_t *cstate);
53 }
54
55 /*
56 * We want a reentrant scanner.
57 */
58 %option reentrant
59
60 /*
61 * And we need to pass the compiler state to the scanner.
62 */
63 %option extra-type="compiler_state_t *"
64
65 /*
66 * We don't use input, so don't generate code for it.
67 */
68 %option noinput
69
70 /*
71 * We don't use unput, so don't generate code for it.
72 */
73 %option nounput
74
75 /*
76 * We don't read from the terminal.
77 */
78 %option never-interactive
79
80 /*
81 * We want to stop processing when we get to the end of the input.
82 */
83 %option noyywrap
84
85 /*
86 * We want to generate code that can be used by a reentrant parser
87 * generated by Bison or Berkeley YACC.
88 */
89 %option bison-bridge
90
91 %{
92 /*
93 * Copyright (c) 1988, 1989, 1990, 1991, 1992, 1993, 1994, 1995, 1996, 1997
94 * The Regents of the University of California. All rights reserved.
95 *
96 * Redistribution and use in source and binary forms, with or without
97 * modification, are permitted provided that: (1) source code distributions
98 * retain the above copyright notice and this paragraph in its entirety, (2)
99 * distributions including binary code include the above copyright notice and
100 * this paragraph in its entirety in the documentation or other materials
101 * provided with the distribution, and (3) all advertising materials mentioning
102 * features or use of this software display the following acknowledgement:
103 * ``This product includes software developed by the University of California,
104 * Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
105 * the University nor the names of its contributors may be used to endorse
106 * or promote products derived from this software without specific prior
107 * written permission.
108 * THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
109 * WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
110 * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
111 */
112
113 #include <string.h>
114
115 #include "pcap-int.h"
116
117 /*
118 * Earlier versions of Flex don't declare these, so we declare them
119 * ourselves to squelch warnings.
120 */
121 int pcap_get_column(yyscan_t);
122 void pcap_set_column(int, yyscan_t);
123
124 #ifdef INET6
125
126 #ifdef _WIN32
127 #include <winsock2.h>
128 #include <ws2tcpip.h>
129 #else /* _WIN32 */
130 #include <sys/socket.h> /* for "struct sockaddr" in "struct addrinfo" */
131 #include <netdb.h> /* for "struct addrinfo" */
132 #endif /* _WIN32 */
133
134 /* Workaround for AIX 4.3 */
135 #if !defined(AI_NUMERICHOST)
136 #define AI_NUMERICHOST 0x04
137 #endif
138
139 #endif /*INET6*/
140
141 #include <pcap/namedb.h>
142 #include "grammar.h"
143
144 #ifdef HAVE_OS_PROTO_H
145 #include "os-proto.h"
146 #endif
147
148 static int stou(const char *, YYSTYPE *, compiler_state_t *);
149
150 /*
151 * Disable diagnostics in the code generated by Flex.
152 */
153 DIAG_OFF_FLEX
154
155 %}
156
157 N ([0-9]+|(0X|0x)[0-9A-Fa-f]+)
158 B ([0-9A-Fa-f][0-9A-Fa-f]?)
159 B2 ([0-9A-Fa-f][0-9A-Fa-f][0-9A-Fa-f][0-9A-Fa-f])
160 W ([0-9A-Fa-f][0-9A-Fa-f]?[0-9A-Fa-f]?[0-9A-Fa-f]?)
161
162 %a 18400
163 %o 21500
164 %e 7600
165 %k 4550
166 %p 27600
167 %n 2000
168
169 V680 {W}:{W}:{W}:{W}:{W}:{W}:{W}:{W}
170
171 V670 ::{W}:{W}:{W}:{W}:{W}:{W}:{W}
172 V671 {W}::{W}:{W}:{W}:{W}:{W}:{W}
173 V672 {W}:{W}::{W}:{W}:{W}:{W}:{W}
174 V673 {W}:{W}:{W}::{W}:{W}:{W}:{W}
175 V674 {W}:{W}:{W}:{W}::{W}:{W}:{W}
176 V675 {W}:{W}:{W}:{W}:{W}::{W}:{W}
177 V676 {W}:{W}:{W}:{W}:{W}:{W}::{W}
178 V677 {W}:{W}:{W}:{W}:{W}:{W}:{W}::
179
180 V660 ::{W}:{W}:{W}:{W}:{W}:{W}
181 V661 {W}::{W}:{W}:{W}:{W}:{W}
182 V662 {W}:{W}::{W}:{W}:{W}:{W}
183 V663 {W}:{W}:{W}::{W}:{W}:{W}
184 V664 {W}:{W}:{W}:{W}::{W}:{W}
185 V665 {W}:{W}:{W}:{W}:{W}::{W}
186 V666 {W}:{W}:{W}:{W}:{W}:{W}::
187
188 V650 ::{W}:{W}:{W}:{W}:{W}
189 V651 {W}::{W}:{W}:{W}:{W}
190 V652 {W}:{W}::{W}:{W}:{W}
191 V653 {W}:{W}:{W}::{W}:{W}
192 V654 {W}:{W}:{W}:{W}::{W}
193 V655 {W}:{W}:{W}:{W}:{W}::
194
195 V640 ::{W}:{W}:{W}:{W}
196 V641 {W}::{W}:{W}:{W}
197 V642 {W}:{W}::{W}:{W}
198 V643 {W}:{W}:{W}::{W}
199 V644 {W}:{W}:{W}:{W}::
200
201 V630 ::{W}:{W}:{W}
202 V631 {W}::{W}:{W}
203 V632 {W}:{W}::{W}
204 V633 {W}:{W}:{W}::
205
206 V620 ::{W}:{W}
207 V621 {W}::{W}
208 V622 {W}:{W}::
209
210 V610 ::{W}
211 V611 {W}::
212
213 V600 ::
214
215 V6604 {W}:{W}:{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
216
217 V6504 ::{W}:{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
218 V6514 {W}::{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
219 V6524 {W}:{W}::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
220 V6534 {W}:{W}:{W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
221 V6544 {W}:{W}:{W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
222 V6554 {W}:{W}:{W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
223
224 V6404 ::{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
225 V6414 {W}::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
226 V6424 {W}:{W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
227 V6434 {W}:{W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
228 V6444 {W}:{W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
229
230 V6304 ::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
231 V6314 {W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
232 V6324 {W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
233 V6334 {W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
234
235 V6204 ::{W}:{W}:{N}\.{N}\.{N}\.{N}
236 V6214 {W}::{W}:{N}\.{N}\.{N}\.{N}
237 V6224 {W}:{W}::{N}\.{N}\.{N}\.{N}
238
239 V6104 ::{W}:{N}\.{N}\.{N}\.{N}
240 V6114 {W}::{N}\.{N}\.{N}\.{N}
241
242 V6004 ::{N}\.{N}\.{N}\.{N}
243
244
245 V6 ({V680}|{V670}|{V671}|{V672}|{V673}|{V674}|{V675}|{V676}|{V677}|{V660}|{V661}|{V662}|{V663}|{V664}|{V665}|{V666}|{V650}|{V651}|{V652}|{V653}|{V654}|{V655}|{V640}|{V641}|{V642}|{V643}|{V644}|{V630}|{V631}|{V632}|{V633}|{V620}|{V621}|{V622}|{V610}|{V611}|{V600}|{V6604}|{V6504}|{V6514}|{V6524}|{V6534}|{V6544}|{V6554}|{V6404}|{V6414}|{V6424}|{V6434}|{V6444}|{V6304}|{V6314}|{V6324}|{V6334}|{V6204}|{V6214}|{V6224}|{V6104}|{V6114}|{V6004})
246
247 MAC ({B}:{B}:{B}:{B}:{B}:{B}|{B}\-{B}\-{B}\-{B}\-{B}\-{B}|{B}\.{B}\.{B}\.{B}\.{B}\.{B}|{B2}\.{B2}\.{B2}|{B2}{3})
248
249
250
251 %%
252 dst return DST;
253 src return SRC;
254
255 link|ether|ppp|slip return LINK;
256 fddi|tr|wlan return LINK;
257 arp return ARP;
258 rarp return RARP;
259 ip return IP;
260 sctp return SCTP;
261 tcp return TCP;
262 udp return UDP;
263 icmp return ICMP;
264 igmp return IGMP;
265 igrp return IGRP;
266 pim return PIM;
267 vrrp return VRRP;
268 carp return CARP;
269 radio return RADIO;
270
271 ip6 return IPV6;
272 icmp6 return ICMPV6;
273 ah return AH;
274 esp return ESP;
275
276 atalk return ATALK;
277 aarp return AARP;
278 decnet return DECNET;
279 lat return LAT;
280 sca return SCA;
281 moprc return MOPRC;
282 mopdl return MOPDL;
283
284 iso return ISO;
285 esis return ESIS;
286 es-is return ESIS;
287 isis return ISIS;
288 is-is return ISIS;
289 l1 return L1;
290 l2 return L2;
291 iih return IIH;
292 lsp return LSP;
293 snp return SNP;
294 csnp return CSNP;
295 psnp return PSNP;
296
297 clnp return CLNP;
298
299 stp return STP;
300
301 ipx return IPX;
302
303 netbeui return NETBEUI;
304
305 host return HOST;
306 net return NET;
307 mask return NETMASK;
308 port return PORT;
309 portrange return PORTRANGE;
310 proto return PROTO;
311 protochain return PROTOCHAIN;
312
313 gateway return GATEWAY;
314
315 type return TYPE;
316 subtype return SUBTYPE;
317 direction|dir return DIR;
318 address1|addr1 return ADDR1;
319 address2|addr2 return ADDR2;
320 address3|addr3 return ADDR3;
321 address4|addr4 return ADDR4;
322 ra return RA;
323 ta return TA;
324
325 less return LESS;
326 greater return GREATER;
327 byte return CBYTE;
328 broadcast return TK_BROADCAST;
329 multicast return TK_MULTICAST;
330
331 and|"&&" return AND;
332 or|"||" return OR;
333 not return '!';
334
335 len|length return LEN;
336 inbound return INBOUND;
337 outbound return OUTBOUND;
338
339 ifindex return IFINDEX;
340
341 vlan return VLAN;
342 mpls return MPLS;
343 pppoed return PPPOED;
344 pppoes return PPPOES;
345 geneve return GENEVE;
346
347 lane return LANE;
348 llc return LLC;
349 metac return METAC;
350 bcc return BCC;
351 oam return OAM;
352 oamf4 return OAMF4;
353 oamf4ec return OAMF4EC;
354 oamf4sc return OAMF4SC;
355 sc return SC;
356 ilmic return ILMIC;
357 vpi return VPI;
358 vci return VCI;
359 connectmsg return CONNECTMSG;
360 metaconnect return METACONNECT;
361
362 on|ifname return PF_IFNAME;
363 rset|ruleset return PF_RSET;
364 rnr|rulenum return PF_RNR;
365 srnr|subrulenum return PF_SRNR;
366 reason return PF_REASON;
367 action return PF_ACTION;
368
369 fisu return FISU;
370 lssu return LSSU;
371 lsu return LSSU;
372 msu return MSU;
373 hfisu return HFISU;
374 hlssu return HLSSU;
375 hmsu return HMSU;
376 sio return SIO;
377 opc return OPC;
378 dpc return DPC;
379 sls return SLS;
380 hsio return HSIO;
381 hopc return HOPC;
382 hdpc return HDPC;
383 hsls return HSLS;
384
385 [ \r\n\t] ;
386 [+\-*/%:\[\]!<>()&|\^=] return yytext[0];
387 ">=" return GEQ;
388 "<=" return LEQ;
389 "!=" return NEQ;
390 "==" return '=';
391 "<<" return LSH;
392 ">>" return RSH;
393 ${B} { yylval->s = sdup(yyextra, yytext); return AID; }
394 {MAC} { yylval->s = sdup(yyextra, yytext); return EID; }
395 {N} { return stou(yytext, yylval, yyextra); }
396 ({N}\.{N})|({N}\.{N}\.{N})|({N}\.{N}\.{N}\.{N}) {
397 yylval->s = sdup(yyextra, (char *)yytext); return HID; }
398 {V6} {
399 #ifdef INET6
400 struct addrinfo hints, *res;
401 memset(&hints, 0, sizeof(hints));
402 hints.ai_family = AF_INET6;
403 hints.ai_flags = AI_NUMERICHOST;
404 if (getaddrinfo(yytext, NULL, &hints, &res)) {
405 bpf_set_error(yyextra, "bogus IPv6 address %s", yytext);
406 yylval->s = NULL;
407 } else {
408 freeaddrinfo(res);
409 yylval->s = sdup(yyextra, (char *)yytext);
410 }
411 #else
412 bpf_set_error(yyextra, "IPv6 address %s not supported", yytext);
413 yylval->s = NULL;
414 #endif /*INET6*/
415 return HID6;
416 }
417 {B}:+({B}:+)+ { bpf_set_error(yyextra, "bogus ethernet address %s", yytext); yylval->s = NULL; return EID; }
418 icmptype { yylval->h = 0; return NUM; }
419 icmpcode { yylval->h = 1; return NUM; }
420 icmp-echoreply { yylval->h = 0; return NUM; }
421 icmp-unreach { yylval->h = 3; return NUM; }
422 icmp-sourcequench { yylval->h = 4; return NUM; }
423 icmp-redirect { yylval->h = 5; return NUM; }
424 icmp-echo { yylval->h = 8; return NUM; }
425 icmp-routeradvert { yylval->h = 9; return NUM; }
426 icmp-routersolicit { yylval->h = 10; return NUM; }
427 icmp-timxceed { yylval->h = 11; return NUM; }
428 icmp-paramprob { yylval->h = 12; return NUM; }
429 icmp-tstamp { yylval->h = 13; return NUM; }
430 icmp-tstampreply { yylval->h = 14; return NUM; }
431 icmp-ireq { yylval->h = 15; return NUM; }
432 icmp-ireqreply { yylval->h = 16; return NUM; }
433 icmp-maskreq { yylval->h = 17; return NUM; }
434 icmp-maskreply { yylval->h = 18; return NUM; }
435
436 icmp6type { yylval->h = 0; return NUM; }
437 icmp6code { yylval->h = 1; return NUM; }
438
439 icmp6-destinationunreach { yylval->h = 1; return NUM; }
440 icmp6-packettoobig { yylval->h = 2; return NUM; }
441 icmp6-timeexceeded { yylval->h = 3; return NUM; }
442 icmp6-parameterproblem { yylval->h = 4; return NUM; }
443 icmp6-echo { yylval->h = 128; return NUM; }
444 icmp6-echoreply { yylval->h = 129; return NUM; }
445 icmp6-multicastlistenerquery { yylval->h = 130; return NUM; }
446 icmp6-multicastlistenerreportv1 { yylval->h = 131; return NUM; }
447 icmp6-multicastlistenerdone { yylval->h = 132; return NUM; }
448 icmp6-routersolicit { yylval->h = 133; return NUM; }
449 icmp6-routeradvert { yylval->h = 134; return NUM; }
450 icmp6-neighborsolicit { yylval->h = 135; return NUM; }
451 icmp6-neighboradvert { yylval->h = 136; return NUM; }
452 icmp6-redirect { yylval->h = 137; return NUM; }
453 icmp6-routerrenum { yylval->h = 138; return NUM; }
454 icmp6-nodeinformationquery { yylval->h = 139; return NUM; }
455 icmp6-nodeinformationresponse { yylval->h = 140; return NUM; }
456 icmp6-ineighbordiscoverysolicit { yylval->h = 141; return NUM; }
457 icmp6-ineighbordiscoveryadvert { yylval->h = 142; return NUM; }
458 icmp6-multicastlistenerreportv2 { yylval->h = 143; return NUM; }
459 icmp6-homeagentdiscoveryrequest { yylval->h = 144; return NUM; }
460 icmp6-homeagentdiscoveryreply { yylval->h = 145; return NUM; }
461 icmp6-mobileprefixsolicit { yylval->h = 146; return NUM; }
462 icmp6-mobileprefixadvert { yylval->h = 147; return NUM; }
463 icmp6-certpathsolicit { yylval->h = 148; return NUM; }
464 icmp6-certpathadvert { yylval->h = 149; return NUM; }
465 icmp6-multicastrouteradvert { yylval->h = 151; return NUM; }
466 icmp6-multicastroutersolicit { yylval->h = 152; return NUM; }
467 icmp6-multicastrouterterm { yylval->h = 153; return NUM; }
468
469 tcpflags { yylval->h = 13; return NUM; }
470 tcp-fin { yylval->h = 0x01; return NUM; }
471 tcp-syn { yylval->h = 0x02; return NUM; }
472 tcp-rst { yylval->h = 0x04; return NUM; }
473 tcp-push { yylval->h = 0x08; return NUM; }
474 tcp-ack { yylval->h = 0x10; return NUM; }
475 tcp-urg { yylval->h = 0x20; return NUM; }
476 tcp-ece { yylval->h = 0x40; return NUM; }
477 tcp-cwr { yylval->h = 0x80; return NUM; }
478 [A-Za-z0-9]([-_.A-Za-z0-9]*[.A-Za-z0-9])? {
479 yylval->s = sdup(yyextra, (char *)yytext); return ID; }
480 "\\"[^ !()\n\t]+ { yylval->s = sdup(yyextra, (char *)yytext + 1); return ID; }
481 . { return LEX_ERROR; }
482 %%
483
484 /*
485 * Turn diagnostics back on, so we check the code that we've written.
486 */
487 DIAG_ON_FLEX
488
489 stoulen_ret
490 stoulen(const char *string, size_t string_len, bpf_u_int32 *val,
491 compiler_state_t *cstate)
492 {
493 bpf_u_int32 n = 0;
494 unsigned int digit;
495 const char *s = string;
496
497 /*
498 * string is guaranteed either to be a string of decimal digits
499 * or 0[xX] followed by a string of hex digits.
500 */
501 if (string_len >= 1 && *s == '0') {
502 if (string_len >= 2 && (s[1] == 'x' || s[1] == 'X')) {
503 /*
504 * Begins with 0x or 0X, so hex.
505 * Guaranteed to be all hex digits following the
506 * prefix, so anything that's not 0-9 or a-f is
507 * A-F.
508 */
509 s += 2; /* skip the prefix */
510 string_len -= 2;
511 while (string_len != 0) {
512 digit = *s++;
513 string_len--;
514 if (digit >= '0' && digit <= '9')
515 digit = digit - '0';
516 else if (digit >= 'a' && digit <= 'f')
517 digit = digit - 'a' + 10;
518 else if (digit >= 'A' && digit <= 'F')
519 digit = digit - 'A' + 10;
520 else {
521 /*
522 * Not a valid hex number.
523 * Don't treat this as an error,
524 * in case the caller wants to
525 * interpret it as something else.
526 */
527 return STOULEN_NOT_HEX_NUMBER;
528 }
529
530 /*
531 * Check for overflow.
532 */
533 if (n > 0xFFFFFFFU) {
534 /*
535 * We have more than 28 bits of
536 * number, and are about to
537 * add 4 more; that won't fit
538 * in 32 bits.
539 */
540 bpf_set_error(cstate,
541 "number %.*s overflows 32 bits",
542 (int)string_len, string);
543 return STOULEN_ERROR;
544 }
545 n = (n << 4) + digit;
546 }
547 } else {
548 /*
549 * Begins with 0, but not 0x or 0X, so octal.
550 * Guaranteed to be all *decimal* digits following
551 * the prefix, so we need to catch 8 and 9 and
552 * report an error.
553 */
554 s += 1;
555 string_len -= 1;
556 while (string_len != 0) {
557 digit = *s++;
558 string_len--;
559 if (digit >= '0' && digit <= '7')
560 digit = digit - '0';
561 else {
562 /*
563 * Not a valid octal number.
564 * Don't treat this as an error,
565 * in case the caller wants to
566 * interpret it as something else.
567 */
568 return STOULEN_NOT_OCTAL_NUMBER;
569 }
570 if (n > 03777777777U) {
571 /*
572 * We have more than 29 bits of
573 * number, and are about to add
574 * 3 more; that won't fit in
575 * 32 bits.
576 */
577 bpf_set_error(cstate,
578 "number %.*s overflows 32 bits",
579 (int)string_len, string);
580 return STOULEN_ERROR;
581 }
582 n = (n << 3) + digit;
583 }
584 }
585 } else {
586 /*
587 * Decimal.
588 */
589 while (string_len != 0) {
590 digit = *s++;
591 string_len--;
592 if (digit >= '0' && digit <= '9')
593 digit = digit - '0';
594 else {
595 /*
596 * Not a valid decimal number.
597 * Don't treat this as an error,
598 * in case the caller wants to
599 * interpret it as something else.
600 */
601 return STOULEN_NOT_DECIMAL_NUMBER;
602 }
603 #define CUTOFF_DEC (0xFFFFFFFFU / 10U)
604 #define CUTLIM_DEC (0xFFFFFFFFU % 10U)
605 if (n > CUTOFF_DEC ||
606 (n == CUTOFF_DEC && digit > CUTLIM_DEC)) {
607 /*
608 * Adding that digit will result in a
609 * number that won't fit in 32 bits.
610 */
611 bpf_set_error(cstate,
612 "number %.*s overflows 32 bits",
613 (int)string_len, string);
614 return STOULEN_ERROR;
615 }
616 n = (n * 10) + digit;
617 }
618 }
619
620 *val = n;
621 return STOULEN_OK;
622 }
623
624 /*
625 * Convert string to 32-bit unsigned integer. Just like atoi(), but checks for
626 * preceding 0x or 0 and uses hex or octal instead of decimal.
627 *
628 * On success, sets yylval->h to the value and returns NUM.
629 * On failure, sets the BPF error string and returns LEX_ERROR, to force
630 * the parse to stop.
631 */
632 static int
stou(const char * yytext_arg,YYSTYPE * yylval_arg,compiler_state_t * yyextra_arg)633 stou(const char *yytext_arg, YYSTYPE *yylval_arg, compiler_state_t *yyextra_arg)
634 {
635 stoulen_ret ret;
636
637 ret = stoulen(yytext_arg, strlen(yytext_arg), &yylval_arg->h,
638 yyextra_arg);
639 switch (ret) {
640
641 case STOULEN_OK:
642 return NUM;
643
644 case STOULEN_NOT_OCTAL_NUMBER:
645 bpf_set_error(yyextra_arg, "number %s contains non-octal digit",
646 yytext_arg);
647 return LEX_ERROR;
648
649 case STOULEN_NOT_HEX_NUMBER:
650 bpf_set_error(yyextra_arg, "number %s contains non-hex digit",
651 yytext_arg);
652 return LEX_ERROR;
653
654 case STOULEN_NOT_DECIMAL_NUMBER:
655 bpf_set_error(yyextra_arg, "number %s contains non-decimal digit",
656 yytext_arg);
657 return LEX_ERROR;
658
659 case STOULEN_ERROR:
660 /* Error already set. */
661 return LEX_ERROR;
662
663 default:
664 /* Should not happen */
665 bpf_set_error(yyextra_arg, "stoulen returned %d - this should not happen", ret);
666 return LEX_ERROR;
667 }
668 }
669