1/* SPDX-License-Identifier: GPL-2.0 */
2/*
3 * This is the infamous ld script for the 64 bits vdso
4 * library
5 */
6
7#include <asm/vdso/vsyscall.h>
8#include <asm/page.h>
9#include <asm/vdso.h>
10#include <vdso/datapage.h>
11
12OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
13OUTPUT_ARCH(s390:64-bit)
14
15SECTIONS
16{
17	VDSO_VVAR_SYMS
18
19	. = SIZEOF_HEADERS;
20
21	.hash		: { *(.hash) }			:text
22	.gnu.hash	: { *(.gnu.hash) }
23	.dynsym		: { *(.dynsym) }
24	.dynstr		: { *(.dynstr) }
25	.gnu.version	: { *(.gnu.version) }
26	.gnu.version_d	: { *(.gnu.version_d) }
27	.gnu.version_r	: { *(.gnu.version_r) }
28
29	.note		: { *(.note.*) }		:text	:note
30
31	. = ALIGN(16);
32	.text		: {
33		*(.text .stub .text.* .gnu.linkonce.t.*)
34	} :text
35	PROVIDE(__etext = .);
36	PROVIDE(_etext = .);
37	PROVIDE(etext = .);
38
39	/*
40	 * Other stuff is appended to the text segment:
41	 */
42	.rodata		: { *(.rodata .rodata.* .gnu.linkonce.r.*) }
43	.rodata1	: { *(.rodata1) }
44
45	. = ALIGN(8);
46	.altinstructions	: { *(.altinstructions) }
47	.altinstr_replacement	: { *(.altinstr_replacement) }
48
49	.dynamic	: { *(.dynamic) }		:text	:dynamic
50
51	.eh_frame_hdr	: { *(.eh_frame_hdr) }		:text	:eh_frame_hdr
52	.eh_frame	: { KEEP (*(.eh_frame)) }	:text
53	.gcc_except_table : { *(.gcc_except_table .gcc_except_table.*) }
54
55	.rela.dyn ALIGN(8) : { *(.rela.dyn) }
56	.got ALIGN(8)	: { *(.got .toc) }
57	.got.plt ALIGN(8) : { *(.got.plt) }
58
59	_end = .;
60	PROVIDE(end = .);
61
62	/*
63	 * Stabs debugging sections are here too.
64	 */
65	.stab	       0 : { *(.stab) }
66	.stabstr       0 : { *(.stabstr) }
67	.stab.excl     0 : { *(.stab.excl) }
68	.stab.exclstr  0 : { *(.stab.exclstr) }
69	.stab.index    0 : { *(.stab.index) }
70	.stab.indexstr 0 : { *(.stab.indexstr) }
71	.comment       0 : { *(.comment) }
72
73	/*
74	 * DWARF debug sections.
75	 * Symbols in the DWARF debugging sections are relative to the
76	 * beginning of the section so we begin them at 0.
77	 */
78	/* DWARF 1 */
79	.debug		0 : { *(.debug) }
80	.line		0 : { *(.line) }
81	/* GNU DWARF 1 extensions */
82	.debug_srcinfo	0 : { *(.debug_srcinfo) }
83	.debug_sfnames	0 : { *(.debug_sfnames) }
84	/* DWARF 1.1 and DWARF 2 */
85	.debug_aranges	0 : { *(.debug_aranges) }
86	.debug_pubnames 0 : { *(.debug_pubnames) }
87	/* DWARF 2 */
88	.debug_info	0 : { *(.debug_info .gnu.linkonce.wi.*) }
89	.debug_abbrev	0 : { *(.debug_abbrev) }
90	.debug_line	0 : { *(.debug_line) }
91	.debug_frame	0 : { *(.debug_frame) }
92	.debug_str	0 : { *(.debug_str) }
93	.debug_loc	0 : { *(.debug_loc) }
94	.debug_macinfo	0 : { *(.debug_macinfo) }
95	/* SGI/MIPS DWARF 2 extensions */
96	.debug_weaknames 0 : { *(.debug_weaknames) }
97	.debug_funcnames 0 : { *(.debug_funcnames) }
98	.debug_typenames 0 : { *(.debug_typenames) }
99	.debug_varnames  0 : { *(.debug_varnames) }
100	/* DWARF 3 */
101	.debug_pubtypes 0 : { *(.debug_pubtypes) }
102	.debug_ranges	0 : { *(.debug_ranges) }
103	.gnu.attributes 0 : { KEEP (*(.gnu.attributes)) }
104
105	/DISCARD/	: {
106		*(.note.GNU-stack)
107		*(.branch_lt)
108		*(.data .data.* .gnu.linkonce.d.* .sdata*)
109		*(.bss .sbss .dynbss .dynsbss)
110	}
111}
112
113/*
114 * Very old versions of ld do not recognize this name token; use the constant.
115 */
116#define PT_GNU_EH_FRAME	0x6474e550
117
118/*
119 * We must supply the ELF program headers explicitly to get just one
120 * PT_LOAD segment, and set the flags explicitly to make segments read-only.
121 */
122PHDRS
123{
124	text		PT_LOAD FILEHDR PHDRS FLAGS(5);	/* PF_R|PF_X */
125	dynamic		PT_DYNAMIC FLAGS(4);		/* PF_R */
126	note		PT_NOTE FLAGS(4);		/* PF_R */
127	eh_frame_hdr	PT_GNU_EH_FRAME;
128}
129
130/*
131 * This controls what symbols we export from the DSO.
132 */
133VERSION
134{
135	VDSO_VERSION_STRING {
136	global:
137		/*
138		 * Has to be there for the kernel to find
139		 */
140		__kernel_gettimeofday;
141		__kernel_clock_gettime;
142		__kernel_clock_getres;
143		__kernel_getcpu;
144		__kernel_restart_syscall;
145		__kernel_rt_sigreturn;
146		__kernel_sigreturn;
147		__kernel_getrandom;
148	local: *;
149	};
150}
151