1/* SPDX-License-Identifier: GPL-2.0 */
2/*
3 * This is the infamous ld script for the 64 bits vdso
4 * library
5 */
6
7#include <asm/page.h>
8#include <asm/vdso.h>
9#include <vdso/datapage.h>
10
11OUTPUT_FORMAT("elf32-s390", "elf32-s390", "elf32-s390")
12OUTPUT_ARCH(s390:31-bit)
13
14SECTIONS
15{
16	VDSO_VVAR_SYMS
17
18	. = SIZEOF_HEADERS;
19
20	.hash		: { *(.hash) }			:text
21	.gnu.hash	: { *(.gnu.hash) }
22	.dynsym		: { *(.dynsym) }
23	.dynstr		: { *(.dynstr) }
24	.gnu.version	: { *(.gnu.version) }
25	.gnu.version_d	: { *(.gnu.version_d) }
26	.gnu.version_r	: { *(.gnu.version_r) }
27
28	.note		: { *(.note.*) }		:text	:note
29
30	. = ALIGN(16);
31	.text		: {
32		*(.text .stub .text.* .gnu.linkonce.t.*)
33	} :text
34	PROVIDE(__etext = .);
35	PROVIDE(_etext = .);
36	PROVIDE(etext = .);
37
38	/*
39	 * Other stuff is appended to the text segment:
40	 */
41	.rodata		: { *(.rodata .rodata.* .gnu.linkonce.r.*) }
42	.rodata1	: { *(.rodata1) }
43
44	.dynamic	: { *(.dynamic) }		:text	:dynamic
45
46	.eh_frame_hdr	: { *(.eh_frame_hdr) }		:text	:eh_frame_hdr
47	.eh_frame	: { KEEP (*(.eh_frame)) }	:text
48	.gcc_except_table : { *(.gcc_except_table .gcc_except_table.*) }
49
50	.rela.dyn ALIGN(8) : { *(.rela.dyn) }
51	.got ALIGN(8)	: { *(.got .toc) }
52	.got.plt ALIGN(8) : { *(.got.plt) }
53
54	_end = .;
55	PROVIDE(end = .);
56
57	/*
58	 * Stabs debugging sections are here too.
59	 */
60	.stab	       0 : { *(.stab) }
61	.stabstr       0 : { *(.stabstr) }
62	.stab.excl     0 : { *(.stab.excl) }
63	.stab.exclstr  0 : { *(.stab.exclstr) }
64	.stab.index    0 : { *(.stab.index) }
65	.stab.indexstr 0 : { *(.stab.indexstr) }
66	.comment       0 : { *(.comment) }
67
68	/*
69	 * DWARF debug sections.
70	 * Symbols in the DWARF debugging sections are relative to the
71	 * beginning of the section so we begin them at 0.
72	 */
73	/* DWARF 1 */
74	.debug		0 : { *(.debug) }
75	.line		0 : { *(.line) }
76	/* GNU DWARF 1 extensions */
77	.debug_srcinfo	0 : { *(.debug_srcinfo) }
78	.debug_sfnames	0 : { *(.debug_sfnames) }
79	/* DWARF 1.1 and DWARF 2 */
80	.debug_aranges	0 : { *(.debug_aranges) }
81	.debug_pubnames 0 : { *(.debug_pubnames) }
82	/* DWARF 2 */
83	.debug_info	0 : { *(.debug_info .gnu.linkonce.wi.*) }
84	.debug_abbrev	0 : { *(.debug_abbrev) }
85	.debug_line	0 : { *(.debug_line) }
86	.debug_frame	0 : { *(.debug_frame) }
87	.debug_str	0 : { *(.debug_str) }
88	.debug_loc	0 : { *(.debug_loc) }
89	.debug_macinfo	0 : { *(.debug_macinfo) }
90	/* SGI/MIPS DWARF 2 extensions */
91	.debug_weaknames 0 : { *(.debug_weaknames) }
92	.debug_funcnames 0 : { *(.debug_funcnames) }
93	.debug_typenames 0 : { *(.debug_typenames) }
94	.debug_varnames  0 : { *(.debug_varnames) }
95	/* DWARF 3 */
96	.debug_pubtypes 0 : { *(.debug_pubtypes) }
97	.debug_ranges	0 : { *(.debug_ranges) }
98	.gnu.attributes 0 : { KEEP (*(.gnu.attributes)) }
99
100	/DISCARD/	: {
101		*(.note.GNU-stack)
102		*(.branch_lt)
103		*(.data .data.* .gnu.linkonce.d.* .sdata*)
104		*(.bss .sbss .dynbss .dynsbss)
105	}
106}
107
108/*
109 * Very old versions of ld do not recognize this name token; use the constant.
110 */
111#define PT_GNU_EH_FRAME	0x6474e550
112
113/*
114 * We must supply the ELF program headers explicitly to get just one
115 * PT_LOAD segment, and set the flags explicitly to make segments read-only.
116 */
117PHDRS
118{
119	text		PT_LOAD FILEHDR PHDRS FLAGS(5);	/* PF_R|PF_X */
120	dynamic		PT_DYNAMIC FLAGS(4);		/* PF_R */
121	note		PT_NOTE FLAGS(4);		/* PF_R */
122	eh_frame_hdr	PT_GNU_EH_FRAME;
123}
124
125/*
126 * This controls what symbols we export from the DSO.
127 */
128VERSION
129{
130	VDSO_VERSION_STRING {
131	global:
132		/*
133		 * Has to be there for the kernel to find
134		 */
135		__kernel_compat_restart_syscall;
136		__kernel_compat_rt_sigreturn;
137		__kernel_compat_sigreturn;
138	local: *;
139	};
140}
141