xref: /qemu/ui/meson.build (revision ec7e5a90fea996f04ea24e81b680a87bc975354a) 
1system_ss.add(pixman)
2system_ss.add(png)
3system_ss.add(files(
4  'clipboard.c',
5  'console.c',
6  'cursor.c',
7  'dmabuf.c',
8  'input-keymap.c',
9  'input-legacy.c',
10  'input-barrier.c',
11  'input.c',
12  'kbd-state.c',
13  'keymaps.c',
14  'qemu-pixman.c',
15  'ui-hmp-cmds.c',
16  'ui-qmp-cmds.c',
17  'util.c',
18))
19system_ss.add(when: pixman, if_true: files('console-vc.c'), if_false: files('console-vc-stubs.c'))
20if dbus_display
21  system_ss.add(files('dbus-module.c'))
22endif
23system_ss.add([spice_headers, files('spice-module.c')])
24system_ss.add(when: spice_protocol, if_true: files('vdagent.c'))
25
26if host_os == 'linux'
27  system_ss.add(files('input-linux.c', 'udmabuf.c'))
28endif
29system_ss.add(when: cocoa, if_true: files('cocoa.m'))
30
31vnc_ss = ss.source_set()
32vnc_ss.add(files(
33  'vnc.c',
34  'vnc-enc-zlib.c',
35  'vnc-enc-hextile.c',
36  'vnc-enc-tight.c',
37  'vnc-palette.c',
38  'vnc-enc-zrle.c',
39  'vnc-auth-vencrypt.c',
40  'vnc-ws.c',
41  'vnc-jobs.c',
42  'vnc-clipboard.c',
43))
44vnc_ss.add(zlib, jpeg)
45vnc_ss.add(when: sasl, if_true: files('vnc-auth-sasl.c'))
46system_ss.add_all(when: [vnc, pixman], if_true: vnc_ss)
47system_ss.add(when: vnc, if_false: files('vnc-stubs.c'))
48
49ui_modules = {}
50
51if curses.found()
52  curses_ss = ss.source_set()
53  curses_ss.add(when: [curses, iconv], if_true: [files('curses.c'), pixman])
54  ui_modules += {'curses' : curses_ss}
55endif
56
57system_ss.add(opengl)
58if opengl.found()
59  opengl_ss = ss.source_set()
60  opengl_ss.add(gbm, pixman)
61  opengl_ss.add(when: [opengl],
62               if_true: files('shader.c', 'console-gl.c', 'egl-helpers.c', 'egl-context.c'))
63  ui_modules += {'opengl' : opengl_ss}
64endif
65
66if opengl.found()
67  egl_headless_ss = ss.source_set()
68  egl_headless_ss.add(when: [opengl, pixman],
69                      if_true: [files('egl-headless.c'), gbm])
70  ui_modules += {'egl-headless' : egl_headless_ss}
71endif
72
73if dbus_display
74  dbus_ss = ss.source_set()
75  env = environment()
76  env.set('HOST_OS', host_os)
77  xml = custom_target('dbus-display preprocess',
78                      input: 'dbus-display1.xml',
79                      output: 'dbus-display1.xml',
80                      env: env,
81                      command: [xml_pp, '@INPUT@', '@OUTPUT@'])
82  dbus_display1 = custom_target('dbus-display gdbus-codegen',
83                                output: ['dbus-display1.h', 'dbus-display1.c'],
84                                input: xml,
85                                command: [gdbus_codegen, '@INPUT@',
86                                          '--glib-min-required', '2.64',
87                                          '--output-directory', meson.current_build_dir(),
88                                          '--interface-prefix', 'org.qemu.',
89                                          '--c-namespace', 'QemuDBus',
90                                          '--generate-c-code', '@BASENAME@'])
91  dbus_ss.add(when: gio,
92              if_true: [files(
93                'dbus-chardev.c',
94                'dbus-clipboard.c',
95                'dbus-console.c',
96                'dbus-error.c',
97                'dbus-listener.c',
98                'dbus.c',
99              ), opengl, gbm, pixman, dbus_display1])
100  ui_modules += {'dbus' : dbus_ss}
101endif
102
103if gtk.found()
104  if host_os == 'windows'
105    system_ss.add(files('win32-kbd-hook.c'))
106  endif
107
108  gtk_ss = ss.source_set()
109  gtk_ss.add(gtk, vte, pixman, files('gtk.c'))
110  if have_gtk_clipboard
111    gtk_ss.add(files('gtk-clipboard.c'))
112  endif
113  gtk_ss.add(when: x11, if_true: files('x_keymap.c'))
114  gtk_ss.add(when: opengl, if_true: files('gtk-gl-area.c'))
115  gtk_ss.add(when: [x11, opengl], if_true: files('gtk-egl.c'))
116  ui_modules += {'gtk' : gtk_ss}
117endif
118
119if sdl.found()
120  sdl_ss = ss.source_set()
121  sdl_ss.add(sdl, sdl_image, pixman, glib, files(
122    'sdl2-2d.c',
123    'sdl2-input.c',
124    'sdl2.c',
125  ))
126  sdl_ss.add(when: opengl, if_true: files('sdl2-gl.c'))
127  sdl_ss.add(when: x11, if_true: files('x_keymap.c'))
128  ui_modules += {'sdl' : sdl_ss}
129endif
130
131if spice.found()
132  spice_core_ss = ss.source_set()
133  spice_core_ss.add(spice, pixman, files(
134    'spice-core.c',
135    'spice-input.c',
136    'spice-display.c'
137  ))
138  ui_modules += {'spice-core' : spice_core_ss}
139
140  if gio.found()
141    spice_ss = ss.source_set()
142    spice_ss.add(spice, gio, pixman, files('spice-app.c'))
143    ui_modules += {'spice-app': spice_ss}
144  endif
145endif
146
147keymaps = [
148  ['atset1', 'qcode'],
149  ['linux', 'qcode'],
150  ['qcode', 'atset1'],
151  ['qcode', 'atset2'],
152  ['qcode', 'atset3'],
153  ['qcode', 'linux'],
154  ['qcode', 'qnum'],
155  ['qcode', 'sun'],
156  ['qnum', 'qcode'],
157  ['usb', 'qcode'],
158  ['win32', 'qcode'],
159  ['x11', 'qcode'],
160  ['xorgevdev', 'qcode'],
161  ['xorgkbd', 'qcode'],
162  ['xorgxquartz', 'qcode'],
163  ['xorgxwin', 'qcode'],
164  ['osx', 'qcode'],
165]
166
167if have_system or xkbcommon.found()
168  keycodemapdb_proj = subproject('keycodemapdb', required: true)
169  foreach e : keymaps
170    output = 'input-keymap-@0@-to-@1@.c.inc'.format(e[0], e[1])
171    genh += custom_target(output,
172                  output: output,
173                  capture: true,
174                  input: keycodemapdb_proj.get_variable('keymaps_csv'),
175                  command: [python, keycodemapdb_proj.get_variable('keymap_gen').full_path(),
176                            'code-map', '--lang', 'glib2',
177                            '--varname', 'qemu_input_map_@0@_to_@1@'.format(e[0], e[1]),
178                            '@INPUT0@', e[0], e[1]])
179  endforeach
180endif
181
182subdir('shader')
183
184if have_system
185  subdir('icons')
186
187  install_data('qemu.desktop', install_dir: qemu_desktopdir)
188endif
189
190modules += {'ui': ui_modules}
191