xref: /qemu/qapi/meson.build (revision 9761ad5f65d23f080b5a3479e52196fbce2e1506) 
1util_ss.add(files(
2  'opts-visitor.c',
3  'qapi-clone-visitor.c',
4  'qapi-dealloc-visitor.c',
5  'qapi-forward-visitor.c',
6  'qapi-util.c',
7  'qapi-visit-core.c',
8  'qobject-input-visitor.c',
9  'qobject-output-visitor.c',
10  'string-input-visitor.c',
11  'string-output-visitor.c',
12))
13if have_system
14  util_ss.add(files('qapi-type-helpers.c'))
15endif
16if have_system or have_tools or have_ga
17  util_ss.add(files(
18    'qmp-dispatch.c',
19    'qmp-event.c',
20    'qmp-registry.c',
21  ))
22endif
23
24qapi_all_modules = [
25  'authz',
26  'block',
27  'block-core',
28  'block-export',
29  'char',
30  'common',
31  'compat',
32  'control',
33  'crypto',
34  'cxl',
35  'dump',
36  'ebpf',
37  'error',
38  'introspect',
39  'job',
40  'machine-common',
41  'machine',
42  'machine-s390x',
43  'migration',
44  'misc',
45  'net',
46  'pragma',
47  'qom',
48  'replay',
49  'run-state',
50  'sockets',
51  'stats',
52  'trace',
53  'transaction',
54  'vfio',
55  'virtio',
56  'yank',
57]
58if have_system
59  qapi_all_modules += [
60    'acpi',
61    'audio',
62    'cryptodev',
63    'qdev',
64    'pci',
65    'rocker',
66    'misc-arm',
67    'misc-i386',
68    'tpm',
69    'uefi',
70  ]
71endif
72if have_system or have_tools
73  qapi_all_modules += [
74    'ui',
75  ]
76endif
77
78qapi_nonmodule_outputs = [
79  'qapi-introspect.c', 'qapi-introspect.h',
80  'qapi-types.c', 'qapi-types.h',
81  'qapi-visit.h', 'qapi-visit.c',
82  'qapi-commands.h', 'qapi-commands.c',
83  'qapi-init-commands.h', 'qapi-init-commands.c',
84  'qapi-events.h', 'qapi-events.c',
85  'qapi-emit-events.c', 'qapi-emit-events.h',
86]
87
88qapi_outputs = qapi_nonmodule_outputs + [
89  'qapi-builtin-types.c', 'qapi-builtin-visit.c',
90  'qapi-builtin-types.h', 'qapi-builtin-visit.h',
91]
92
93qapi_inputs = []
94foreach module : qapi_all_modules
95  qapi_inputs += [ files(module + '.json') ]
96  qapi_module_outputs = [
97    'qapi-types-@0@.c'.format(module),
98    'qapi-types-@0@.h'.format(module),
99    'qapi-visit-@0@.c'.format(module),
100    'qapi-visit-@0@.h'.format(module),
101  ]
102  if have_system or have_tools
103    qapi_module_outputs += [
104      'qapi-events-@0@.c'.format(module),
105      'qapi-events-@0@.h'.format(module),
106      'qapi-commands-@0@.c'.format(module),
107      'qapi-commands-@0@.h'.format(module),
108      'qapi-commands-@0@.trace-events'.format(module),
109    ]
110  endif
111  qapi_outputs += qapi_module_outputs
112endforeach
113
114qapi_files = custom_target('shared QAPI source files',
115  output: qapi_outputs,
116  input: [ files('qapi-schema.json') ],
117  command: [ qapi_gen, '-o', 'qapi', '-b', '@INPUT0@' ],
118  depend_files: [ qapi_inputs, qapi_gen_depends ])
119
120i = 0
121foreach output : qapi_outputs
122  if output.endswith('.h')
123    genh += qapi_files[i]
124  endif
125  if output.endswith('.trace-events')
126    qapi_trace_events += qapi_files[i]
127  endif
128  util_ss.add(qapi_files[i])
129  i = i + 1
130endforeach
131