xref: /kvm-unit-tests/powerpc/flat.lds (revision a41100276a89128703db61361f6be878c6473005) 
1
2PHDRS
3{
4    text PT_LOAD FLAGS(5);
5    data PT_LOAD FLAGS(6);
6}
7
8SECTIONS
9{
10    .text : {
11        *(.init)
12        *(.text)
13        *(.text.*)
14    } :text
15    . = ALIGN(64K);
16    etext = .;
17    .opd : { *(.opd) }
18    . = ALIGN(16);
19    .dynamic : {
20        dynamic_start = .;
21        *(.dynamic)
22    }
23    .dynsym : {
24        dynsym_start = .;
25        *(.dynsym)
26    }
27    .rela.dyn : { *(.rela*) }
28    . = ALIGN(16);
29    .data : {
30        *(.data)
31        *(.data.rel*)
32    } :data
33    . = ALIGN(16);
34    .rodata : {
35        *(.rodata)
36        *(.rodata.*)
37    } :data
38    . = ALIGN(16);
39    .bss : { *(.bss) }
40    . = ALIGN(256);
41    /*
42     * tocptr is tocbase + 32K, allowing toc offsets to be +-32K
43     */
44    tocptr = . + 32K;
45    .got : { *(.toc) *(.got) }
46    . = ALIGN(64K);
47    edata = .;
48    . += 64K;
49    . = ALIGN(64K);
50    /*
51     * stackptr set with initial stack frame (64 bytes) preallocated
52     */
53    stackptr = . - 64;
54    stacktop = .;
55}
56
57ENTRY(start)
58